Public Enum LanguageEnum
    General = 1
    Arabic = 2
    SimplifiedChinese = 3
    TraditionalChinese = 4
    Russian = 5
    Czech = 6
    Dutch = 7
    Greek = 8
    Hebrew = 9
    Hungarian = 10
    Icelandic = 11
    Japanese = 12
    Korean = 13
    NorwegianAndDanish = 14
    Polish = 15
    Slovenian = 16
    TraditionalSpanish = 17
    SwedishAndFinnish = 18
    Thai = 19
    Turkish = 20
End Enum

Public Function CreateNewDatabase(ByRef strDBName As String, _
                                  ByRef Language As LanguageEnum, _
                                  ByRef DatabaseFormat As DatabaseTypeEnum) As Database
    Dim ws As Workspace
    Dim prp As DAO.Property
    Dim strLanguage As String
    
    Select Case Language
        Case General: strLanguage = dbLangGeneral
        Case Arabic: strLanguage = dbLangArabic
        Case SimplifiedChinese: strLanguage = dbLangChineseSimplified
        Case TraditionalChinese: strLanguage = dbLangChineseTraditional
        Case Russian: strLanguage = dbLangCyrillic
        Case Czech: strLanguage = dbLangCzech
        Case Dutch: strLanguage = dbLangDutch
        Case Greek: strLanguage = dbLangGreek
        Case Hebrew: strLanguage = dbLangHebrew
        Case Hungarian: strLanguage = dbLangHungarian
        Case Icelandic: strLanguage = dbLangIcelandic
        Case Japanese: strLanguage = dbLangJapanese
        Case Korean: strLanguage = dbLangKorean
        Case NorwegianAndDanish: strLanguage = dbLangNorwDan
        Case Polish: strLanguage = dbLangPolish
        Case Slovenian: strLanguage = dbLangSlovenian
        Case TraditionalSpanish: strLanguage = dbLangSpanish
        Case SwedishAndFinnish: strLanguage = dbLangSwedFin
        Case Thai: strLanguage = dbLangThai
        Case Turkish: strLanguage = dbLangTurkish
    End Select
    
    'Get the default Workspace.
    Set ws = DBEngine(0)
    
    'Make sure there isn't already a database with the same filespec.
    If Len(Dir(strDBName)) > 0 Then
        DoCmd.Beep
        If vbYes = MsgBox("A database with this name already exists." & vbCrLf & _
                          "Do you want to replace it with the new database?", _
                          vbYesNo + vbQuestion, "Duplicate database name") Then
            
            Kill strDBName
        Else
            Set CreateNewDatabase = Nothing
            GoTo Proc_Exit
        End If
    End If
    
    'Create the new database, and return a reference to it.
    Set CreateNewDatabase = ws.CreateDatabase(strDBName, strLanguage, DatabaseFormat)

    'Create example properties in new database.
    With CreateNewDatabase
        Set prp = .CreateProperty("Perform Name AutoCorrect", dbLong, 0)
        .Properties.Append prp
        Set prp = .CreateProperty("Track Name AutoCorrect Info", dbLong, 0)
        .Properties.Append prp
    End With
    
Proc_Exit:
    Set ws = Nothing
    Set prp = Nothing
End Function