'***************************************
' Code for opening several databases.
'***************************************
Public Sub OpenSeveralDatabases(strUsrName As String, strPwd As String)
    Dim wsJet As Workspace
    Dim wsODBC As Workspace
    Dim dbJet As Database
    Dim dbdBase As Database
    Dim dbODBC As Database
    Dim dbODBCDirect As Database
    Dim dbODBCDirect1 As Database
    Dim cn As Connection
    
    'Create the Jet and ODBCDirect workspaces
    Set wsJet = DBEngine(0)
    Set wsODBC = DBEngine.CreateWorkspace( _
        "", strUsrName, strPwd, dbUseODBC)

    
    'Print the details for the default database
    Debug.Print "Jet Database "; wsJet.Databases.Count & _
        " - " & CurrentDb.Name
    
    'Open a Microsoft Jet database - shared - read-only
    Set dbJet = wsJet.OpenDatabase("C:\Temp\db1.mdb", False, True)
    Debug.Print "Jet Database "; wsJet.Databases.Count & _
        " - " & dbJet.Name
    
    'Open a dBase IV database - exclusive - read-write
    Set dbdBase = wsJet.OpenDatabase( _
        "dBase IV;DATABASE=C:\Temp\db2.dbf", True, False)
    Debug.Print "Database "; wsJet.Databases.Count & _
        " - " & dbdBase.Name
    
    'Open an ODBC database using a DSN - exclusive - read-only
    Set dbODBC = wsJet.OpenDatabase( _
        "", dbDriverComplete, True, "ODBC;DATABASE=myDB;DSN=myDSN")
    Debug.Print "Jet Database "; wsJet.Databases.Count & _
        " - " & dbODBC.Name
    
    'Open an ODBCDirect Connection using a DSN - read-only
    Set cn = wsODBC.OpenConnection( _
        "", dbDriverComplete, True, "ODBC;DATABASE=myDB;DSN=myDSN")
    'Get a reference to the default ODBCDirect database
    Set dbODBCDirect = wsODBC.Databases(0)
     ‘This could so be written as: Set dbODBCDirect = cn.Database
    Debug.Print "ODBCDirect Database "; wsODBC.Databases.Count & _
        " - " & dbODBCDirect.Name
    
    'Open a second database reference using the ODBCDirect connection
    Set dbODBCDirect1 = wsODBC.OpenDatabase( _
        "", dbDriverComplete, True, "ODBC;DATABASE=myDB;DSN=myDSN")
    Debug.Print "ODBCDirect Database "; wsODBC.Databases.Count & _
        " - " & dbODBCDirect.Name
    
    'Clean up
    cn.Close
    wsJet.Close
    wsODBC.Close
    Set dbJet = Nothing
    Set dbdBase = Nothing
    Set dbODBC = Nothing
    Set dbODBCDirect = Nothing
    Set dbODBCDirect1 = Nothing
    Set cn = Nothing
    Set wsJet = Nothing
    Set wsODBC = Nothing
End Sub